Github Repo Terraform 으로 초기설정하기

Terraform 은 IAC 툴이다. Terraform 에 등록된 provider 에는 AWS, Azure, GCP 등 당연한 벤더들이 있는데, 그 중에는 Github 도 있다. 즉 Github Resource 들을 Terraform 으로 관리할 수 있다는 얘기다.

그중에서 Github Repository 를 생성할 때 Terraform 을 사용하는 방법을 알아본다.

Terraform 으로 Repo 관리

단순히 생각하면 장점이 없는 것 같지만, Github 으로 issue tracking 을 하는 경우라면 아래와 같은 기본적인 것들이 필요하다.

Issue 라벨

기본적으로 필요한 배포 파이프라인을 위한 Issue 목록

배포 파이프 라인 구축을 위한 마일스톤

위와같은 세팅을 매번 UI 로 하나하나 설정해야 하는 일을 한번의 command 로 마무리 할 수 있다.

Prerequisite

terraform

예시를 따라가려면 terraform 이 필요하다. 설치되어있지 않다면 아래 링크를 참고해서 미리 설치하자.

https://developer.hashicorp.com/terraform/install?product_intent=terraform

Github Token

Repo 생성을 위해 Token 이 필요하다. GITHUB PAT 중 classic token 으로 생성한다. 필요한 권한은 아래와 같다.

repo

delete_repo

project

Terraform Provider

테라폼으로 Github 관련 기능을 사용하려면 먼저 Provider 설정을 해야한다. provider 설정은 terraform 문서를 참고한다. 링크의 우측 상단에 USE PROVIDER 버튼을 누르면 확인할 수 있다. GITHUB

아무 디렉토리나 만들고 하위에 main.tf 파일을 작성한다. owner 의 value 는 실제 github username 으로 변경한다.


terraform {
  required_providers {
    github = {
      source  = "integrations/github"
      version = "6.4.0"
    }
  }
}

provider "github" {
  owner = "GIHUB_USERNAME"
}

main.tf 파일이 있는 디렉토리에서 terraform init 을 한다.

성공시 Terraform has been successfully initialized! 를 볼 수 있고, 디렉토리에 terraform lock file 이 생긴다.


resource "github_repository" "tf-ex" {
  name                   = "tf-ex"
  description            = "Repository made by terraform"
  visibility             = "private"
  has_issues             = true
  auto_init              = true
  gitignore_template     = "Terraform"
  delete_branch_on_merge = true
}

main.tf 에 위 코드를 추가한다.

기본적으로 terraform 은 plan 으로 현재 infra 와의 변경사항이 있는지 체크하고 apply 로 적용한다.

terraform plan 을 하면 repo 가 하나 생긴다고 한다. terraform apply 후 yes 를 해보자.

401 에러가 난다. 권한 검증에 실패해서 그렇다.

이전에 Prerequisite 에서 준비한 github 토큰을 설정하고 다시 apply 를 해보자.


GITHUB_TOKEN="YOUT_TOKEN" terraform apply

정상작동하는것을 확인할 수 있다.

GITHUB web 에서 repository 추가를 확인할 수 있다.


GITHUB_TOKEN="YOUT_TOKEN" terraform destroy

위 명령어로는 repo 를 지울 수 있다.

repo 생성 삭제만으로는 terraform 을 사용하는 의미가 없다. milestone, issue, issue-label 을 추가하자.

같은 디렉토리에 variables.tf 파일을 생성한다.


variable "milestones" {
  type = map(object({
    title       = string
    due_date    = string
    description = string
  }))
}

variable "labels" {
  type = map(object({
    name  = string
    color = string
  }))
}

variable "issues" {
  type = list(object({
    title     = string
    body      = string
    labels    = list(string)
    milestone = string
  }))
}

milestone, issue-label, issue 를 등록하기 위한 기본 자료구조를 정의한다. type 은 임의로 만든게 아니다. terraform registry 의 github provider 에서 제공하는 각 resource 별 예시 타입을 참고해서 생성하면 된다. ex) Github Issue

다만 위와같이 issue 는 milestone_number 를 지정해서 등록해야 하는데, milestone 생성 전까지 number 를 알 수 없으므로 milestone title 값을 받도록 하는 약간의 custom 이 가미된 구조이다. 추후 생성된 mileston tf resource 에 접근해서 milestone number 를 획득해서 사용하도록 하면 된다.

하나만 등록할 게 아니라서 전부 map, list 로 정의한다.

main.tf 에 아래 코드를 추가한다.


resource "github_repository_milestone" "epics" {
  for_each    = var.milestones
  owner       = local.github_owner
  repository  = github_repository.tf-ex.name
  title       = each.value.title
  description = replace(each.value.description, "\n", " ")
  due_date    = each.value.due_date
}

resource "github_issue_label" "issue_labels" {
  for_each   = var.labels
  repository = github_repository.tf-ex.name
  name       = each.value.name
  color      = each.value.color
}

resource "github_issue" "tasks" {
  count            = length(var.issues)
  repository       = github_repository.tf-ex.name
  title            = var.issues[count.index].title
  milestone_number = github_repository_milestone.epics[var.issues[count.index].milestone].number
  labels           = [for l in var.issues[count.index].labels : github_issue_label.issue_labels[l].name]
}

HCL 언어의 문법을 설명하지 않아도 대강 읽어보면 알 수 있다. map 에서 key 를 따와서 epic, issue_labels resource 를 정의하고 issue 는 배열에서 가져오는 코드이다.

이 상태에서 terraform plan 을 하면 issue 의 값을 입력하라고 prompt 가 뜬다. 당연하게 자료구조만 정의하고 실제 data 를 입력하지 않아서 실행 시점에 요구하는 것이다.

ctrl + c 로 취소하고 실제로 적용될 값들을 만들어보자.

.auto.tfvars 를 아래와 같이 생성한다. 예시로 사용할 milestone, label, issue 데이터이다.


milestones = {
  "infrastructure" = {
    title       = "Infrastructure"
    due_date    = "2025-01-31"
    description = "서버 Infra 구축"
  },
  "ci-cd" = {
    title       = "CI / CD"
    due_date    = "2025-02-07"
    description = "CI CD 구축"
  }
}

labels = {
  "kind-infrastructure" = {
    name  = "Kind:Infrastructure"
    color = "B60206"
  },
  "kind-ci-cd" = {
    name  = "Kind:CI-CD"
    color = "FBCA04"
  }
}

issues = [
  {
    title     = "Integration pipelines"
    body      = "Implement a CI pipeline"
    labels    = ["kind-ci-cd"]
    milestone = "ci-cd"
  },
  {
    title     = "Implement the Dockerfile's builder stage"
    body      = "Docker file builder stage 완성하기. compile, test, 및 code formatting 보장하도록"
    labels    = ["kind-infrastructure"]
    milestone = "infrastructure"
  }
]

terraform 은 apply 시 .tfvars 파일을 전부 읽는다. 위와같이 미리 정의할 것들이 있다면 .tfvars 에 정의하면 된다.

apply 를 하면 github repository 에 정상적으로 반영된 것을 볼 수 있다. 각 이슈는 이슈라벨과 마일스톤이 잘 지정되어 있다.

resource 간 순서 보장

resource 정의를 아래와 같이 했다.

눈여겨 볼 부분은 repository 에 “tf-ex” 로 string value 가 아니라 tf resource 를 참조하도록 되어있다. (github_repository.tf-ex.name)

“tf-ex” 로 literal string 을 사용하는 경우 terraform 에서 의존관계를 확인할 수 없다. 이 경우 apply, destory 시 repo 와 다른 resource 간의 생성 및 삭제 순서에 따라 terraform 명령어가 실패한다.

명시적으로 각 resource 에 depends_on 키로 의존성을 명시할 수 있지만, 암시적인 의존성 명시를 사용하면 추후 값이 바뀌는 경우에 자동으로 대응이 되므로 암시적인 의존성 명시를 사용하는 방향이 나은 방법인 것 같다.


resource "github_repository_milestone" "epics" {
  for_each    = var.milestones
  owner       = local.github_owner
  repository  = github_repository.tf-ex.name
  title       = each.value.title
  description = replace(each.value.description, "\n", " ")
  due_date    = each.value.due_date
}

resource "github_issue_label" "issue_labels" {
  for_each   = var.labels
  repository = github_repository.tf-ex.name
  name       = each.value.name
  color      = each.value.color
}

resource "github_issue" "tasks" {
  count            = length(var.issues)
  repository       = github_repository.tf-ex.name
  title            = var.issues[count.index].title
  milestone_number = github_repository_milestone.epics[var.issues[count.index].milestone].number
  labels           = [for l in var.issues[count.index].labels : github_issue_label.issue_labels[l].name]
}

마무리

여기까지 왔다면 terraform destroy 를 해보고 다시 apply 를 해보자. 정상 작동한다면 github repository 생성을 위한 템플릿을 성공적으로 만든 것이다. 축!